目錄隱藏灰

『壹』 文件夾隱藏屬性變成灰色不可用了

這是因為如果他們有系統屬性就無法右鍵屬性設置他們的隱藏屬性.

我寫的這個批處理可以修改磁碟或文件或文件夾內所有文件的系統屬性和隱藏屬性,很方便的.

將以下內容復制到記事本,另存為"修改系統屬性和隱藏屬性.bat"(注意加引號).

用的時候,把要修改屬性的磁碟或文件或文件夾,拖到批處理文件的圖標上(可以拖很多),然後按提示操作就行了.

注意:請把要更改屬性的磁碟或文件或文件夾拖到批處理文件圖標內,不要雙擊運行此批處理.

@echo off
setlocal enabledelayedexpansion
title 修改系統屬性和隱藏屬性
color f0
mode con: cols=50 lines=25
if "%~1"=="" (
echo 你沒有拖入任何磁碟或文件或文件夾
echo 請把要處理的磁碟或文件或文件夾拖到批處理文件圖標
echo 不要雙擊啟動批處理
pause
)
:loop
cls
if "%~1"=="" goto :eof
if not exist "%~1" (echo 路徑不存在)&pause&shift&goto loop
echo 當前處理的磁碟或文件或文件夾:
echo %~1
echo.
echo 請選擇要進行的操作，然後按回車
echo.
echo 加系統和隱藏屬性……………………………1
echo 減系統和隱藏屬性……………………………2
echo 不處理…………………………………………3
echo.
set /p "c1=選擇 (1,2,3) (不輸入為!c1!,默認為2):"
if "!c1!"=="1" (set "d=+") else if "!c1!"=="3" (pause&shift&goto loop) else set "d=-"
set "a=%~a1"
if /i "!a:~0,1!"=="d" (
echo.
echo 這是一個文件夾，請選擇要進行的操作，然後按回車
echo.
echo 只對該文件夾本身……………………………1
echo 只對該文件夾中的文件夾和文件……………2
echo 對該目錄下的一切的文件夾和文件…………3
echo.
set /p "c2=選擇 (1,2,3) (不輸入為!c2!,默認為1):"
if "!c2!"=="2" (
pushd "%~1"
for /f "delims=" %%i in ('dir /a /b "%~1"') do attrib.exe !d!s !d!h "%%i"
popd
) else if "!c2!"=="3" (
for /f "delims=" %%i in ('dir /a /b /s "%~1"') do attrib.exe !d!s !d!h "%%i"
) else (
attrib.exe !d!s !d!h "%~1"
)
) else (
attrib.exe !d!s !d!h "%~1"
)
pause&shift&goto loop

『貳』 word文檔的目錄，突然有了灰色背景，怎麼去掉

1、如圖所示，灰色底紋，可以看出，但是圖片不好列印出來。

『叄』 word文檔的目錄，忽然有了灰色背景，怎麼去掉

那是域底紋，可以通過下面的方法使其不顯示。

1、單擊窗口左上角的回「office按鈕」，在彈答出的下拉選項中單擊「word選項」；

『肆』 文件夾屬性隱藏按鈕為灰色，怎麼辦

我的u盤也和你的有相同事件發生過
與病毒搏鬥的方法如下

插入U盤，點開始——運行，輸入cmd，進入命令控制台；
鍵入X: 其中X表示U盤所在的盤符，後面的冒號是英文半形的；
輸入attrib -s -h *.* /s /d 稍等一會兒，就會看到問題解決了。

附：attrib命令的使用方法：

attrib指令用於修改文件的屬性.文件的常見屬性有:只讀.存檔.隱藏和系統.
只讀屬性是指文件只可以做讀的操作.不能對文件進行寫的操作.就是文件的防寫.
存檔屬性是用來標記文件改動的.即在上一次備份後文件有所改動.一些備份軟體在備份的時候會只去備份帶有存檔屬性的文件.
隱藏屬性顧名思義即為隱藏文件.在通常情況下.在資源管理器中不顯示帶有隱藏屬性的文件.
系統屬性是指標注文件為系統文件.是系統需要調用的文件.

attrib指令的格式和常用參數為

ATTRIB [+R | -R] [+A | -A ] [+S | -S] [+H | -H] [[drive:] [path] filename] [/S [/D]]

+ 設置屬性。
- 清除屬性。
R 只讀文件屬性。
A 存檔文件屬性。
S 系統文件屬性。
H 隱藏文件屬性。
[drive:][path][filename]
指定要處理的文件屬性。
/S 處理當前文件夾及其子文件夾中的匹配文件。
/D 也處理文件夾。

attrib的用途不是很廣泛.不過有的時候可以利用它來做一些方便的文件處理.比如U盤中感染了病毒.會在U盤的驅動器里建立多個隱藏的文件.其中會有一個名為autorun.inf的文件.這個文件會為U盤添加一個自動運行的菜單.如果把默認打開操作改成關聯病毒程序.那麼在你雙擊U盤的時候.就會感染U盤所帶的病毒.通常情況下無法看到這些文件就沒辦法刪除.可以用下面的步驟來清除.
以下假設我的U盤驅動器的盤符是L:.""之間的內容為注釋.在運行中敲入CMD確定便可以快速打開系統的命令提示符.運行的快捷鍵為"WIN"+"R".

C:\Documents and Settings\Administrator>L:
L:\>dir/a
L:\>attrib autorun.inf -a -s -r -h
L:\>del autorun.inf

然後拔掉U盤.再一次連接的時候U盤的自動運行菜單就沒有了.當然.其他的病毒程序也可以如此操作.如果把autorun.inf換成*.*就可以一次對當前目錄下全部文件進行操作了.如:

L:\>attrib *.* -a -s -r -h